fi

Neulich, nach einem Upgrade eines S/4 HANA on Premise Systems, meldete ein Kollege kuriose Vorkommnisse in der SAPGUI Transaktion BP - Pflege Geschäftspartner

Felder waren teilweise überlagert und einzelne Abschnitte fehlten komplett. Bild-/Feldsteuerung, Berechtigungen alles ok. Hier ein Screenshot von einigen Auffälligkeiten:

Abhilfe schafft hier die Anwendung des steinalten, aber immer noch topaktuellen Hinweises 633244 - BP_BDT: Fehlerhafte Anzeige von Bildern und Sichten in Transaktion BP.

Der Hinweis empfiehlt die Ausführung der Transaktion BUSP mit den Parametern:

Dadurch werden alle Subscreens der BP neu generiert.

Im System, in dem das Phänomen nach dem Upgrade aufgetreten war, kam bei Ausführung der BUSP im Protokoll die Fehlermeldung R11-518 hoch, weil ein Bild (BUP060) wohl zu viele Abschnitte aufwies.

Eine kurze Recherche im SAP Hinweissystem brachte den Hinweis 3387098 - Error R11518 occurs when regenerating subscreens with transaction BUSP zu Tage, dessen Anwendung half, den Fehler zu beseitigen und die BUSP fehlerfrei auszuführen.

Anschließend war der Spuk vorbei und die BP-Dynpros sahen wieder vorzeigbar aus.

Mir wäre nicht bekannt, dass es im SAP Standard - egal mit welchem Migrationstool - ein Werkzeug gäbe, mit dem Dauerbuchungs-Urbelege von einem SAP-System in ein anderes migriert werden können. In meinen letzten Kundenprojekten waren jeweils eine stattliche Anzahl von aktiven Dauerbuchungs-Urbelegen im Altsystem vorhanden, so dass eine etwaige manuelle Übernahme, eine veritable Meuterei des Fachbereichs ausgelöst hätte. 

Insofern war es meine Aufgabe, ein entsprechendes Übernahmeprogramm zu schreiben. Eins vorweg: perfekt (oder gar modern) ist es mit Sicherheit nicht. Ich verwende dabei zur Übernahme eine Batch-Input-Mappe, die aus der Liste der Dauerbuchungs-Urbelege aus dem Altsystem (Transaktion F.15) gespeist wird.

D.h. die erste Aufgabe ist, die relevanten, d.h. die zu migrierenden Dauerbuchungs-Urbelege mithilfe der Transaktion F.15 aus dem Altsystem zu extrahieren. Um tatsächlich nur die relevanten Belege zu erwischen, kann bspw. unter Berücksichtigung des Löschkennzeichens bzw. des Beginn/Ende-Datums selektiert werden. Die dann angezeigte Liste kann mithilfe der Menüfunktion "Liste --> Exportieren --> lokale Datei... / Text mit Tabulatoren" heruntergeladen und anschließend wieder in Excel importiert und von dort in eine "uploadbare" Form umgewandelt werden.

In der nachfolgenden Abbildung ist die Struktur der Excel-Datei zu sehen, auf dem das weiter unten stehende Upload-Programm ZFBD1 operiert.

Für einen besseren Überblick über die einzelnen Felder sind nachfolgend die Elemente des Belegkopfes und der Belegpositionen im Detail aufgeführt (sorry für den Deutsch/Englisch Misch-Masch):

Datenstruktur Header:

Datenstruktur Position

Sobald die Vorbereitungen abgeschlossen sind und die Excel-Datei zum Import geeignet aufbereitet ist, kann diese ins Zielsystem geladen werden. Spielen Sie dazu im Zielsystem das untenstehende Programm ein und führen Sie es aus:

• Geben Sie Excel-Datei als Quelldatei an. Sie können die Datei im Excel-Format verwenden, eine vorherige Konvertierung nach CSV o.ä. ist nicht erforderlich.
• Geben Sie die entsprechenden Mappenparameter vor und führen Sie den Report aus.
• Spielen Sie die vom Programm erzeugte Batch-Input-Mappe ab.

*&---------------------------------------------------------------------*
*& Report ZFBD1
*&---------------------------------------------------------------------*
*& Migrationstool Dauerbuchungsurbelege
*&---------------------------------------------------------------------*
REPORT zfbd1
       NO STANDARD PAGE HEADING LINE-SIZE 255.

DATA: data_tab TYPE TABLE OF string.
DATA: BEGIN OF header,
        index     TYPE i,
        bukrs     LIKE t001-bukrs,
        fill1,
        belnr     LIKE bkpf-belnr,
        fill2,
        fill3,
        fill4,
        blart     LIKE bkpf-blart,
        fill5,
        budat(10),
        fill6,
        dbbdt(10),
        fill7,
        dbndt(10),
        dbedt(10),
        dbmon(2),
        dbtag(2),
        dbakz     LIKE bkdf-dbakz,
        dbanz(5),
        dblkz(1),
        xtx(1),
        xblnr     LIKE bkpf-xblnr,
        fill8,
        fill9,
        bktxt     LIKE bkpf-bktxt,
        fill10,
        usnam     LIKE sy-uname,
        erdat     LIKE bkpf-cpudt,
      END OF header.

DATA: BEGIN OF item,
        index     TYPE i,
        buzei     LIKE bseg-buzei,
        bschl     LIKE bseg-bschl,
        fill1,
        umskz     LIKE bseg-umskz,
        umsws(1),
        koart     LIKE bseg-koart,
        fill2,
        konto     LIKE bseg-hkont,
        fill3,
        mwskz     LIKE bseg-mwskz,
        fill4,
        mwsbt(16),
        fill5,
        fill6,
        dmbtr(16),
        fill7,
        fill8,
        fill9,
        fill10,
        fill11,
        fill12,
        hwaer(5),
        wrbtr(16),
        sgtxt     LIKE bseg-sgtxt,
        fwaer(5),
        kostl     LIKE bseg-kostl,
        pspnr     LIKE bseg-projn,
      END OF item.

DATA: db_headers LIKE header OCCURS 0.
DATA: db_items  LIKE item OCCURS 0.

DATA: cnt_items_high TYPE i,
      cnt_items      TYPE i.

INCLUDE bdcrecx1_s.
PARAMETERS: pa_fnam LIKE rlgrap-filename OBLIGATORY.

*&---------------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR pa_fnam.
*&---------------------------------------------------------------------*
  PERFORM f4_filename.

*&---------------------------------------------------------------------*
START-OF-SELECTION.
*&---------------------------------------------------------------------*

  PERFORM upload_data.

  IF db_headers[] IS INITIAL.
    MESSAGE i600(fr) WITH 'Keine Dauerbuch.belege' 'zur Migration gefunden'.
    LEAVE PROGRAM.
  ENDIF.
  PERFORM open_group.

  LOOP AT db_headers INTO header.
    PERFORM fbd1_header.

    CLEAR cnt_items_high.
    LOOP AT db_items INTO item WHERE index = header-index.
      ADD 1 TO cnt_items_high.
    ENDLOOP.
    CLEAR cnt_items.

    LOOP AT db_items INTO item WHERE index = header-index.
      ADD 1 TO cnt_items.
      IF item-koart = 'K'.
        IF cnt_items = cnt_items_high.
          PERFORM dynpro_0302_with_posting.
        ELSE.
          PERFORM dynpro_0302.
        ENDIF.
      ELSEIF item-koart = 'D'.
        IF cnt_items = cnt_items_high.
          PERFORM dynpro_0301_with_posting.
        ELSE.
          PERFORM dynpro_0301.
        ENDIF.
      ELSE.
        IF cnt_items = cnt_items_high.
          PERFORM dynpro_0300_with_posting.
        ELSE.
          PERFORM dynpro_0300.
        ENDIF.
      ENDIF.
    ENDLOOP.

    PERFORM bdc_transaction USING 'FBD1'.

  ENDLOOP.

  PERFORM close_group.

*&---------------------------------------------------------------------*
*& Form F4_FILENAME
*&---------------------------------------------------------------------*
*& F4 Hilfe Excel-Datei
*&---------------------------------------------------------------------*
FORM f4_filename .

  CALL FUNCTION 'FAA_FILE_F4'
    EXPORTING
      i_default_extension = 'XLS'
    IMPORTING
      e_filename          = pa_fnam
    EXCEPTIONS
      interface_error     = 1
      OTHERS              = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form UPLOAD_DATA
*&---------------------------------------------------------------------*
*& Anlagendatei uploaden
*&---------------------------------------------------------------------*
FORM upload_data .

  DATA: l_buf    TYPE string,
        l_tabix  TYPE sy-tabix,
        l_bukrs  TYPE t001-bukrs,
        l_header TYPE abap_bool.

  CLEAR data_tab[].

  CALL FUNCTION 'FAA_FILE_UPLOAD_EXCEL'
    EXPORTING
      i_filename           = pa_fnam
      i_delimiter          = '~'
    TABLES
      et_filecontent       = data_tab
    EXCEPTIONS
      error_accessing_file = 1
      OTHERS               = 2.

  IF sy-subrc <> 0.
    WRITE: / 'Fehler', sy-subrc, 'beim Upload der Datei', pa_fnam.
  ENDIF.

  LOOP AT data_tab INTO l_buf.
    CHECK sy-tabix > 2. "Skip headers
    l_bukrs = l_buf(4).
    SELECT SINGLE COUNT(*) FROM t001 WHERE bukrs = l_bukrs.
    IF sy-subrc = 0.
      l_header = abap_true.
    ELSE.
      l_header = abap_false.
    ENDIF.
    CASE l_header.
      WHEN abap_true.
        ADD 1 TO l_tabix.
        CLEAR header.
        header-index = l_tabix.
        SPLIT l_buf AT '~' INTO
            header-bukrs
            header-fill1
            header-belnr
            header-fill2
            header-fill3
            header-fill4
            header-blart
            header-fill5
            header-budat
            header-fill6
            header-dbbdt
            header-fill7
            header-dbndt
            header-dbedt
            header-dbmon
            header-dbtag
            header-dbakz
            header-dbanz
            header-dblkz
            header-xtx
            header-xblnr
            header-fill8
            header-fill9
            header-bktxt
            header-fill10
            header-usnam
            header-erdat.
        APPEND header TO db_headers.
      WHEN OTHERS.
        CLEAR item.
        item-index = l_tabix.
        SPLIT l_buf AT '~' INTO
            item-buzei
            item-bschl
            item-fill1
            item-umskz
            item-umsws
            item-koart
            item-fill2
            item-konto
            item-fill3
            item-mwskz
            item-fill4
            item-mwsbt
            item-fill5
            item-fill6
            item-dmbtr
            item-fill7
            item-fill8
            item-fill9
            item-fill10
            item-fill11
            item-fill12
            item-hwaer
            item-wrbtr
            item-sgtxt
            item-fwaer
            item-kostl
            item-pspnr.
        TRANSLATE item-mwsbt USING '- '.
        CONDENSE  item-mwsbt NO-GAPS.
        TRANSLATE item-dmbtr USING '- '.
        CONDENSE  item-dmbtr NO-GAPS.
        TRANSLATE item-wrbtr USING '- '.
        CONDENSE  item-wrbtr NO-GAPS.
        APPEND item TO db_items.
    ENDCASE.
  ENDLOOP.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form fbd1_header
*&---------------------------------------------------------------------*
*& Dauerbuchungen Kopfdaten
*&---------------------------------------------------------------------*
FORM fbd1_header .

  REFRESH bdcdata.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0106'.
  PERFORM bdc_field       USING 'BDC_CURSOR'
                                'RF05A-NEWKO'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'BKPF-BUKRS'
                                header-bukrs.
  PERFORM bdc_field       USING 'BKDF-DBBDT'
                                header-dbbdt.
  PERFORM bdc_field       USING 'BKDF-DBEDT'
                                header-dbedt.
  PERFORM bdc_field       USING 'BKDF-DBMON'
                                header-dbmon.
  PERFORM bdc_field       USING 'BKDF-DBTAG'
                                header-dbtag.
  PERFORM bdc_field       USING 'BKPF-BLART'
                                header-blart.
  READ TABLE db_items WITH KEY index = header-index INTO item.
  PERFORM bdc_field       USING 'BKPF-WAERS'
                                item-fwaer.
  PERFORM bdc_field       USING 'BKPF-XBLNR'
                                header-xblnr.
  PERFORM bdc_field       USING 'BKPF-BKTXT'
                                header-bktxt.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0302
*&---------------------------------------------------------------------*
*& Fill Dynpro 0302
*&---------------------------------------------------------------------*
FORM dynpro_0302 .
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                 item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0302'.
  PERFORM bdc_field       USING 'BDC_CURSOR'
                                'RF05A-NEWKO'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF header-xtx NE 'X'.
    PERFORM bdc_field       USING 'BSEG-WMWST'
                                item-mwsbt.
  ENDIF.
  PERFORM bdc_field       USING 'BKPF-XMWST'
                                header-xtx.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.

  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field     USING 'BSEG-MWSKZ'
                                item-mwskz.
  ENDIF.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0300
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM dynpro_0300 .
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0300'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field       USING 'BSEG-MWSKZ'
                                  item-mwskz.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  IF item-kostl IS NOT INITIAL OR item-pspnr IS NOT INITIAL.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'DKACB-FMORE'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  'X'.
    PERFORM bdc_dynpro      USING 'SAPLKACB' '0002'.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'COBL-KOSTL'.
    PERFORM bdc_field       USING 'BDC_OKCODE'
                                  '=ENTE'.
    IF item-kostl IS NOT INITIAL.
      PERFORM bdc_field       USING 'COBL-KOSTL'
                                    item-kostl.
    ELSE.
      PERFORM bdc_field       USING 'COBL-PS_POSID'
                                    item-pspnr.
    ENDIF.
    PERFORM bdc_dynpro      USING 'SAPMF05A' '0300'.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'BSEG-SGTXT'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  ' '.
    PERFORM bdc_field       USING 'BDC_OKCODE'
                                  '/00'.
  ELSE.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'DKACB-FMORE'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  ' '.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field       USING 'BSEG-MWSKZ'
                                  item-mwskz.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0302_with_posting
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM dynpro_0302_with_posting .
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                          item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0302'.
  PERFORM bdc_field       USING 'BDC_CURSOR'
                                'RF05A-NEWKO'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=BU'.
  PERFORM bdc_field       USING 'BKPF-XMWST'
                                header-xtx.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF header-xtx NE 'X'.
    PERFORM bdc_field       USING 'BSEG-WMWST'
                                item-mwsbt.
  ENDIF.

  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field     USING 'BSEG-MWSKZ'
                                item-mwskz.
  ENDIF.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0300_with_posting
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM dynpro_0300_with_posting .
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.

  PERFORM bdc_dynpro      USING 'SAPMF05A' '0300'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=BU'.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field       USING 'BSEG-MWSKZ'
                                  item-mwskz.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  IF item-kostl IS NOT INITIAL OR item-pspnr IS NOT INITIAL.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'DKACB-FMORE'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  'X'.
    PERFORM bdc_dynpro      USING 'SAPLKACB' '0002'.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'COBL-KOSTL'.
    PERFORM bdc_field       USING 'BDC_OKCODE'
                                  '=ENTE'.
    IF item-kostl IS NOT INITIAL.
      PERFORM bdc_field       USING 'COBL-KOSTL'
                                    item-kostl.
    ELSE.
      PERFORM bdc_field       USING 'COBL-PS_POSID'
                                    item-pspnr.
    ENDIF.
    PERFORM bdc_dynpro      USING 'SAPMF05A' '0300'.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'BSEG-SGTXT'.
    PERFORM bdc_field       USING 'BDC_OKCODE'
                                  '=BU'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  ' '.
  ELSE.
    PERFORM bdc_field       USING 'BDC_CURSOR'
                                  'DKACB-FMORE'.
    PERFORM bdc_field       USING 'DKACB-FMORE'
                                  ' '.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field       USING 'BSEG-MWSKZ'
                                  item-mwskz.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                               '=BU'.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0301
*&---------------------------------------------------------------------*
*& Fill Dynpro 0301
*&---------------------------------------------------------------------*
FORM dynpro_0301.
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                        item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0301'.
  PERFORM bdc_field       USING 'BDC_CURSOR'
                                'RF05A-NEWKO'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '/00'.
  PERFORM bdc_field       USING 'BKPF-XMWST'
                                header-xtx.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF header-xtx NE 'X'.
    PERFORM bdc_field       USING 'BSEG-WMWST'
                                item-mwsbt.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field     USING 'BSEG-MWSKZ'
                                item-mwskz.
  ENDIF.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form dynpro_0301_with_posting
*&---------------------------------------------------------------------*
*& text
*&---------------------------------------------------------------------*
*& -->  p1        text
*& <--  p2        text
*&---------------------------------------------------------------------*
FORM dynpro_0301_with_posting .
  PERFORM bdc_field       USING 'RF05A-NEWBS'
                                          item-bschl.
  PERFORM bdc_field       USING 'RF05A-NEWKO'
                                item-konto.
  PERFORM bdc_dynpro      USING 'SAPMF05A' '0301'.
  PERFORM bdc_field       USING 'BDC_CURSOR'
                                'RF05A-NEWKO'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=BU'.
*  PERFORM bdc_field       USING 'BDC_OKCODE'
*                                '/00'.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF header-xtx NE 'X'.
    PERFORM bdc_field       USING 'BSEG-WMWST'
                                item-mwsbt.
  ENDIF.
  PERFORM bdc_field       USING 'BSEG-SGTXT'
                                item-sgtxt.
  PERFORM bdc_field       USING 'BSEG-WRBTR'
                                item-wrbtr.
  IF item-mwskz IS NOT INITIAL.
    PERFORM bdc_field     USING 'BSEG-MWSKZ'
                                item-mwskz.
  ENDIF.
  " PERFORM bdc_field       USING 'BDC_OKCODE'
  "                                '=BU'.
  PERFORM bdc_field       USING 'BKPF-XMWST'
                                header-xtx.
ENDFORM.

Wer schon mal im Customizing der Budgetierung, speziell im Bereich der Verfügbarkeitskontrolle unterwegs war (z.B. im Kontext Projektcontrolling oder Investitionsmanagement), wird beim Einstellen der Toleranzen festgestellt haben, dass man bei Überschreitung einer gewissen Budget-Ausschöpfung die Auswahl zwischen drei System-Aktionen hat:

• Warnung
• Fehlermeldung
• Warnung mit Mail an den Verantwortlichen

Beim Punkt "Warnung mit Mail an Verantwortlichen" kamen (zumindest bei mir) etliche Fragen auf, z.B.:

• Wer ist dieser Verantwortliche in diesem Zusammenhang?
• Wohin wird die Mail eigentlich geschickt?
• Was steht da genau drin?
• Kann man das irgendwie beeinflussen?
• Warum habe ich nix anständiges gelernt...?

Der für das jeweilige PSP-Element bzw. für den Innenauftrag Verantwortliche wird in den Stammdaten zugeordnet. Während bei den Innenaufträgen direkt der entsprechende SAP-User im Feld "Verantwortlicher Benutzer" eingetragen wird...

... wird beim PSP-Element der Verantwortliche mit Schlüssel und Klarnamen im Customizing definiert und dort der korrespondierende SAP-User zugeordnet.

Im Stammsatz des PSP-Elementes selbst, wird dann der Schlüssel hinterlegt:

Für den Fall, dass man im Customizing der Toleranzen die Aktion "Warnung mit Mail an Verantwortlichen" ausgewählt hat aber zu einem Objekt KEIN Verantwortlicher gepflegt ist, wird aus der Warnung eine Fehlermeldung (natürlich ohne Mail, an wen auch...?).

Ohne weiteres Zutun wird die "Mail" als interne SAP-Office-Nachricht an den Business Workplace des jeweiligen verantwortlichen SAP-User gesendet.

Die Nachricht ist dabei wie folgt aufgebaut:

Das funktioniert soweit gut, d.h. wem das genügt, braucht hier nichts weiter einzustellen. Vermutlich wird man sich jedoch einigen weitergehenden Anforderungen gegenüber sehen, z.B. den Inhalt oder Betreff der Mail zu beeinflussen oder die Nachricht als "richtige" Mail an ein externes Mail-System zu senden. 

Per Customizing geht hier leider nix. Aber es gibt eine SAP-Erweiterung, mit der man z.B. die Mail-Adressaten überschreiben und die interne Nachricht in eine externe Mail "umwandeln" kann.

Zudem gibt es einen Userexit, mit dem gewisse Eigenschaften der Mail verändert werden können. So kann z.B. ein Verfallsdatum hinzugefügt oder der Betreff angepasst werden. Der Inhalt, d.h. der Text der Mail ist leider ohne Modifikation nicht beeinflussbar, dazu aber später mehr. 

SAP-Erweiterung zur Bestimmung des/der Mailempfänger/s

Beispiel-Coding:

*&---------------------------------------------------------------------*
*& Include          ZXBPFCU01
*&---------------------------------------------------------------------*
* in standard, the message will be sent to the business workplace of
* the SAP user, that is assigned as responsible for the PSP
* element or internal order. We want to send the warning mail
* to the responsible user's regular mail account (e.g. Outlook)

DATA: lt_return  TYPE TABLE OF bapiret2,
      lt_addsmtp TYPE TABLE OF bapiadsmtp.

* In case, responsible in the master data of the PSP element or
* int. order is not maintained, this table is empty and an error
* message will be thrown in the calling application.
CHECK t_mail_receivers[] IS NOT INITIAL.

* As only one responsible can be assigned, we take the first entry
READ TABLE t_mail_receivers INDEX 1 ASSIGNING FIELD-SYMBOL(<ls_mail_receiver>).
CHECK sy-subrc = 0 AND <ls_mail_receiver> IS ASSIGNED.

* Now we replace the SAP-User with the external EMail address. We retrieve
* that from their user data.

* Switch recipient adress type to external email address:
<ls_mail_receiver>-recesc = 'U'.

* Retrieve & set Email-Adress
CALL FUNCTION 'BAPI_USER_GET_DETAIL'
  EXPORTING
    username = <ls_mail_receiver>-recnam
  TABLES
    return   = lt_return
    addsmtp  = lt_addsmtp.

CHECK lt_addsmtp[] IS NOT INITIAL.
READ TABLE lt_addsmtp INDEX 1 ASSIGNING FIELD-SYMBOL(<ls_addsmtp>).
IF sy-subrc = 0 AND <ls_addsmtp> IS ASSIGNED.
  <ls_mail_receiver>-recextnam = <ls_addsmtp>-e_mail.
ENDIF.

Die Tabelle T_MAIL_RECEIVERS darf dabei auch mehrere Empfänger enthalten. Um bspw. CC oder BCC-Empfänger hinzuzufügen, sind die Tabellenfelder SNDBC (BCC) bzw. SNDCP (CC) des entsprechenden Eintrags mit 'X' zu belegen.

Userexit

Im Hinweis 879732 wird ein Userexit beschrieben, mit dem gewisse Mail-Attribute beeinflusst werden können. Nachfolgend einige Coding-Beispiele für typische Anwendungsfälle.

*&---------------------------------------------------------------------*
*& Subroutinenpool ZMAILHDR
*&---------------------------------------------------------------------*
*& Change mail properties for mails created by availability control
*& See SAP-Note 879732 for details
*&---------------------------------------------------------------------*
PROGRAM zmailhdr.

FORM mail_header_adjust
  CHANGING c_sood1 LIKE sood1.
* Adjust header of mails sent along with warnings
* of availability control.

** Example: Determine an expiry date.
** Option 1 - Expiry date = end of this year.
*  C_SOOD1-DLDAT+0(4) = SY-DATLO(4).
*  C_SOOD1-DLDAT+4(4) = '1231'.
** Option 2 - Expiry date = current date + 4 weeks.
*  C_SOOD1-DLDAT = SY-DATLO + 28.

** Example: Change Mail subject
*  c_sood1-OBJDES = 'My subject'.

ENDFORM.

Mail-Inhalt

Der Inhalt der Mail ist leider nicht ohne Modifikation veränderbar. Es wird hierbei der Langtext der entsprechenden Warnmeldung, die bei der Belegerfassung geworfen wird, verwendet und noch um gewisse hart codierte Bestandteile ergänzt.

Falls es doch jemand anpassen will/muss: Der Zusammenbau des Textes findet im Funktionsbaustein BP_CREATE_MAIL, Zeilen 94ff statt.

In neueren Releases wird die Nachbearbeitung der elektronischen Kontoauszüge (zumindest bei den noch immer zahlreich vorhandenen Fans des SAP-GUI) gerne mithilfe der Transaktion FEB_BSPROC erledigt. Sie kann zugegebenermaßen nicht alles, was die korrespondierende FIORI-App drauf hat (z.B. die Definition eigener Buchungsregeln während der Bearbeitung), aber sie verrichtet nach wie vor zuverlässig ihren Dienst in vielen Bankbuchhaltungsabteilungen.

Ab und zu wurde ich in der Vergangenheit gefragt, ob kundeneigene Informationen in irgendeiner Form (modifikationsfrei!) in die beliebte GUI-Transaktion integriert bzw. in ihr dargestellt werden können. Daraufhin habe ich mich mal damit beschäftigt und zu meiner Überraschung tatsächlich nur einen BTE gefunden, der in diese Richtung zielt.

Es ist z.B. leider nicht möglich, die Arbeitsliste mit den Einzelsätzen im oberen Bereich der Transaktion um eigene, d.h. nicht in der Tabelle FEBEP vorhandene Felder zu erweitern.

Es ist jedoch möglich, im unteren Abschnitt der Transaktion einen eigenen Reiter mit entsprechendem Subscreen einzufügen, in dem kundeneigene Informationen ermittelt/berechnet und dargestellt werden können (hier als Beispiel "Saldo"):

Dies lässt sich mit dem Business Transaction Event 00002840 (P&S-Schnittstelle) bewerkstelligen.

Informationen zu Implementierung von BTEs finden sich u.a. hier.

Im konkreten Fall wird der Musterfunktionsbaustein zum o.g. BTE (SAMPLE_INTERFACE_00002840) in den Kundennamensraum kopiert und die Exportparameter mit folgenden Daten versorgt: 

  e_dynnr = '0100'.
  e_repid = 'SAPLZBTE'.
  e_appl_tab_title = 'Saldo'.

  gs_febep = i_febep.

Sofern Daten aus der Anwendung zur Bereitstellung der gewünschten Informationen im Subscreen benötigt werden, können diese hier in das globale Gedächtnis der Funktionsgruppe kopiert werden, damit auf diese später im Dynpro zugegriffen werden kann (hier bspw. der Inhalt des aktuell bearbeiteten Einzelsatzes).
 

Der Ausgestaltung des Subscreens sind nun kaum noch Grenzen gesetzt und hängt natürlich von der konkreten Anforderung ab. Ich hatte mal eine Anfrage, bei der es dem Anwender ermöglicht werden sollte, das Hauptbuch während der Bearbeitung mit den bereits verbuchten Auszugspositionen abzustimmen. Hierzu sollte der Saldo des Bankkontos 'realtime' dem Saldo des Kontoauszugs gegenübergestellt werden. Letztendlich ist es hierbei nicht zu einer Umsetzung gekommen, deshalb ist das unten aufgeführte Beispiel noch im "Mock-Up"-Status...

Generell ist die ALE-Schnittstelle für FI-Belege (FIDCC1/2) ziemlich restriktiv, was die Verteilung von Sonderhauptbuchbelegen angeht. Im SAP-Hinweis 114814, Punkt 14. wird darauf explizit eingegangen:

Auszug aus HW 114814:

14. Sonderhauptbuchvorgänge SHBV
-------------------------------

Sonderhauptbuchvorgänge sind:

• Anzahlungen
• Anzahlungsanforderungen
• Wechsel
• sonstige

Beim SAP-Verteilungsszenario für FI-Belege wird davon ausgegangen, daß es sich bei den dezentralen Sender-Systemen um z.B. Logistik-Systeme handelt. Das zentrale Empfänger-System ist das FI-Buchhaltungssystem, in dem alle operativen Prozesse, wie Zahlen, Mahnen usw., stattfinden.
Unter dieser Voraussetzung erscheint das Buchen von Belegen mit Sonderhauptbuchvorgängen (SHBV), ausgenommen Anzahlungsanforderungen, nur im zentralen System sinnvoll. Mit anderen Worten, es besteht keine Notwendigkeit, SHBV in den dezentralen Systemen zu buchen und per ALE zu versenden.

Deshalb wird im SAP-Standard das Versenden von SHBV aus einem dezentralen System heraus nicht unterstützt.
Ist der Nachrichtentyp FIDCC1 oder FIDCC2 aktiv, ist es zwar möglich, im dezentralen System Belege mit SHBV zu buchen und auch zu versenden (außer Anzahlungsanforderungen), aber es ist nicht gewährleistet, daß im Empfängersystem aus diesem IDoc erfolgreich ein FI-Beleg gebucht werden kann.
Versendet der Anwender trotzdem SHBV aus dem dezentralen System, liegt es in seiner Verantwortung und Kontrolle, daß der SHBV-Beleg im Empfängersystem auch erfolgreich, vollständig und richtig verbucht wird.

Ursachen für eventuell auftretende Fehler sind:

• Der FI-Beleg und das daraus resultierende IDoc beinhalten u.U. nicht alle notwendigen Felder. Z.B. fehlt für den SHBV 'Wechsel' die Struktur BSED.
• Die RW-Schnittstelle zum Buchen der IDOC-Belege kann nicht alle SHBV verarbeiten, weil die entsprechenden Felder in den Übergabestrukturen ACCIT usw. fehlen. 'Wechsel' werden beispielsweise im RWIN sofort abgewiesen mit der Fehlermeldung: F5 246 Sonderhauptbuchvorgänge der Klasse W werden nicht unterstützt.

(Technisch: In der RW-Schnittstelle werden SHBV-Belege mit BSEG-UMSKS='W' und BKPF-BSTAT='S' nicht verbucht.)

Allerdings kann man in der Regel bei einer reinen FI-Buchung davon ausgehen, daß beim erfolgreichen Einbuchen eines IDoc-Beleges im Empfängersystem, d.h. wenn keine Fehlermeldung auftritt, der SHBV-Beleg tatsächlich vollständig und richtig verbucht wurde.
So könnte es möglich sein, daß beispielsweise reine FI-Anzahlungen erfolgreich verarbeitet werden können. Anzahlungen mit Zusatzkontierungen, z.B. auf Bestellungen, Anlagen, Aufträge, werden nicht vollständig verbucht.
Bei Bestellungen wird die Bestellhistorie nicht fortgeschrieben. Die Bestellungen werden sofort ausgeglichen, es ist keine Verrechnung möglich.
Bei Anlagen werden keine zusätzlichen Verrechnungszeilen erzeugt.
Bei Aufträgen wird kein Anzahlungs-Obligo fortgeschrieben.
Sollte der Anwender trotzdem SHBV aus dem dezentralen System versenden wollen, sind entsprechende Tests des Anwenders unerläßlich!

Anzahlungsanforderungen können im SAP-Standard nicht per ALE versendet werden.
Es ist wegen der Vielzahl der Möglichkeiten, wie ein Anwender ALE FI verwendet, auch nicht geplant (,weil nicht möglich), dafür eine Standardlösung zu entwickeln.
Allerdings ist es im Rahmen einer Kunden-Projektlösung möglich und wurde auch bereits realisiert, entsprechend der speziellen Konstellation beim Anwender, ein Verteilen von Anzahlungsanforderungen zu ermöglichen (-> SAP Beratung).
 

Genau so eine "Kunden-Projektlösung" zu finden, wie im oben rot markierten Abschnitt erwähnt, war gerade meine Aufgabe in meinem aktuellen Kundenprojekt. Es ist hierbei ein zwei System-Szenario gegeben, d.h. ein bestehendes ECC Logistiksystem soll an ein neues S/4-FI/CO System angebunden werden. Wegen der hohen Lizenzkosten und der begrenzten Lebensdauer dieses Szenarios (das Logistiksystem soll im zweiten Schritt ebenfalls in das S/4-System einziehen) wurde der von der SAP favorisierte Central Finance (CFIN) Ansatz verworfen und stattdessen auf ALE-Verteilung gesetzt. Dabei wurden die bekannten Restriktionen, was u.a. SHB-Vorgänge angeht, evaluiert und in Kauf genommen.

Was jedoch (kreditorische) Anzahlungsanforderungen angeht, musste ein Workaround her, da diese Vorgänge zum Teil vom Rechnungsworkflow-System, welches wiederum an das ECC Logistiksystem angebunden ist, ausgelöst werden. D.h., wir mussten einen Weg finden, die Anzahlungsanforderungen am "Türsteher" vorbeizukriegen, damit diese Merkposten vom ECC ans S/4-System verteilt werden, weil dort logischerweise der Zahllauf stattfindet.

 Die Schwierigkeit bei einem komplexen System wie SAP ist, erstmal die Tür zu finden, um im Endeffekt den Türsteher zu lokalisieren. Damit Euch die Suche erspart bleibt, hier die (mir bekannten) Türsteher:

1. Funktionsbaustein FI_IDOC_UPDATE, Zl. 96ff.:

  IF NOT T_BKPF-BSTAT IS INITIAL.
      CHECK X_GLFLEX_ACTIVE = 'X' AND "NewGL ist aktiv
            T_BKPF-BSTAT    = 'L'.    "Buchung in nicht führendes Ledger
  ENDIF.

Bei Belegen mit Belegstatus ungleich leer, werden hier nur solche durchgelassen, die den Belegstatus L (Ledgerspezifische Buchung bei aktivem NewGL) tragen. D.h., Merkposten mit Belegstatus S, wozu ja auch die Anzahlungsanforderungen gehören, haben hier keine Chance. 

Um die Tür auch für Merkposten aufzumachen, muss diese Stelle geeignet modifiziert werden, z.B. so:  

IF NOT T_BKPF-BSTAT IS INITIAL.    
   if not ( t_bkpf-bstat = 'S' and line_exists( t_bseg[ umsks = 'A' ] ) ). "<<<<INSERT
   CHECK X_GLFLEX_ACTIVE = 'X' AND "NewGL ist aktiv
            T_BKPF-BSTAT    = 'L'.    "Buchung in nicht führendes Ledger
   ENDIF.     "<<<<INSERT                                                             
 ENDIF.

2. Funktionsbaustein FI_IDOC_PREPARE, Zl. 260ff.:

* Belegstatus prüfen (keine Muster-, Dauerbuchungsurbelege versenden)
    IF NOT t_bkpf-bstat IS INITIAL.
      IF x_send_c3 = 'X'.
        CHECK x_glflex_active = 'X' AND "NewGL ist aktiv
              ( t_bkpf-bstat    = 'L' OR t_bkpf-bstat    = 'S' ).    "Buchung in nicht führendes Ledger + Anzahlungsanf.
      ELSE.
        CHECK x_glflex_active = 'X' AND "NewGL ist aktiv
              t_bkpf-bstat    = 'L'.    "Buchung in nicht führendes Ledger
      ENDIF.
    ENDIF. 

Anzahlungsanforderungen (BKPF-BSTAT = 'S') werden hier nur durchgelassen, wenn NewGL aktiv ist und der NewGL-Nachrichtentyp FAGLDT01 verwendet wird. Um Merkposten auch bei nicht aktivem NewGL und Verwendung der Nachrichtentypen FIDCC1 bzw. FIDCC2 zu verteilen, muss der o.g. Abschnitt entsprechend modifiziert werden z.B. so:

* Belegstatus prüfen (keine Muster-, Dauerbuchungsurbelege versenden)
    IF NOT t_bkpf-bstat IS INITIAL.
    if not ( t_bkpf-bstat = 'S' and line_exists( t_bseg[ umsks = 'A' ] ) ). "<<<<INSERT
      IF x_send_c3 = 'X'.
        CHECK x_glflex_active = 'X' AND "NewGL ist aktiv
              ( t_bkpf-bstat    = 'L' OR t_bkpf-bstat    = 'S' ).    "Buchung in nicht führendes Ledger + Anzahlungsanf.
      ELSE.
        CHECK x_glflex_active = 'X' AND "NewGL ist aktiv
              t_bkpf-bstat    = 'L'.    "Buchung in nicht führendes Ledger
      ENDIF.
    endif.    "<<<<INSERT
    ENDIF. 

Wie im eingangs erwähnten SAP-Hinweis beschrieben, müssen solche Eingriffe in die Verteilungslogik natürlich umfänglich getestet werden. Ich habe allerdings zumindest bei der Verteilung von Anzahlungsanforderungen bisher keine unerwünschten Seiteneffekte feststellen können.

Öfter habe ich in letzter Zeit in einschlägigen Foren Anfragen bezüglich einer Möglichkeit gelesen, bereits gebuchte Belege per ALE in ein anderes System zu replizieren. Ohne weiteres ist dies ja nur für neu gebuchte Belege nach der Einrichtung des entsprechenden ALE-Verteilungsszenarios möglich. SAP ruft hierzu im Standard-Ablauf den Funktionsbaustein FI_IDOC_CREATE_FIDCC2 auf. 

Mithilfe eines kundeneigenen Programms kann dieser bei Bedarf auch verwendet werden, um Belege, die vor Einrichtung des ALE-Szenarios gebucht wurden, in das Ziel-System zu replizieren.

Tatsächlich ist eine 1:1-Verteilung vergleichsweise einfach zu programmieren, siehe nachfolgendes Coding-Beispiel...

*&---------------------------------------------------------------------*
*& Report Y_MIGRATE_OPS
*&---------------------------------------------------------------------*
*& REPLICATE FI DOCUMENTS VIA ALE DISTRIBUTION - SAMPLE PROGRAM
*&---------------------------------------------------------------------*
REPORT y_replicate_fidocs.
DATA: lt_bkpf TYPE TABLE OF bkpf,
      lt_bseg TYPE TABLE OF bseg,
      lt_bset TYPE TABLE OF bset.
DATA: lt_bkpf_sel TYPE TABLE OF bkpf.
DATA: lv_ownsys LIKE tbdls-logsys.
DATA: lv_buk_global TYPE t001-bukrs_glob.
DATA: ls_bkpf TYPE bkpf.
DATA: lv_prot_title TYPE lvc_title.
SELECT-OPTIONS: so_bukrs FOR ls_bkpf-bukrs,
                so_belnr FOR ls_bkpf-belnr,
                so_gjahr FOR ls_bkpf-gjahr.
PARAMETERS:     pa_logsy LIKE tbd03-rcvsystem OBLIGATORY.
PARAMETERS:     pa_xtest AS CHECKBOX DEFAULT 'X'.

START-OF-SELECTION.
  CALL FUNCTION 'OWN_LOGICAL_SYSTEM_GET'
    IMPORTING
      own_logical_system = lv_ownsys.
 

  SELECT * FROM bkpf INTO TABLE lt_bkpf_sel
      WHERE bukrs IN so_bukrs
        AND belnr IN so_belnr
        AND gjahr IN so_gjahr.

  LOOP AT lt_bkpf_sel INTO ls_bkpf.
    CLEAR: lt_bkpf[].
    APPEND ls_bkpf TO lt_bkpf.
    CLEAR: lt_bseg[], lt_bset[].
    SELECT * FROM bseg INTO TABLE lt_bseg
        WHERE belnr = ls_bkpf-belnr
          AND bukrs = ls_bkpf-bukrs
          AND gjahr = ls_bkpf-gjahr.
    SELECT * FROM bset INTO TABLE lt_bset
        WHERE belnr = ls_bkpf-belnr
          AND bukrs = ls_bkpf-bukrs
          AND gjahr = ls_bkpf-gjahr.

    SELECT SINGLE bukrs_glob FROM t001 INTO lv_buk_global
        WHERE bukrs = ls_bkpf-bukrs.

    IF pa_xtest IS INITIAL.

      SET UPDATE TASK LOCAL.
      CALL FUNCTION 'FI_IDOC_CREATE_FIDCC2'
        EXPORTING
          i_sendsys    = lv_ownsys
          i_recsys     = pa_logsy
          i_bukrs_glob = lv_buk_global
        TABLES
          t_bkpf       = lt_bkpf
          t_bseg       = lt_bseg
          t_bset       = lt_bset
        EXCEPTIONS
          error        = 1
          OTHERS       = 2.

      COMMIT WORK AND WAIT.

    ENDIF.

  ENDLOOP.

  IF pa_xtest = abap_true.
    lv_prot_title = 'TEST RUN - List of documents to be replicated - NO IDOCS GENERATED!!!'.
  ELSE.
    lv_prot_title = 'PROD RUN - List of replicated documents - IDOCS WERE GENERATED!!!'.
  ENDIF.

  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_structure_name = 'BKPF'
      i_grid_title     = lv_prot_title
    TABLES
      t_outtab         = lt_bkpf_sel.

Sofern Mappings / Veränderungen einzelner Datenfelder erforderlich sind, müssten diese natürlich noch in das o.g. Coding integriert werden.

Öfters kam in Kundenprojekten die Anforderung hoch, Informationen aus dem Kontierungshandbuch dem Belegerfasser während des Buchungsvorganges zugänglich zu machen. Eins vorweg: eine 1A-Lösung, die unabhängig vom verwendeten User-Interface funktioniert, habe ich bisher noch nicht gefunden, aber immerhin eine, die modifikationsfrei eingebaut werden kann und zumindest mal bei den gängigen GUI-Transaktionen (FB01, FB50, FB60 etc.) funktioniert. Sie fusst auf dem Business Transaction Event-Framework (BTE) und setzt voraus, dass die Informationen zum Kontierungshandbuch in Form von Standardtexten am Sachkontenstamm vorliegen. Für die Implementierung sind zumindest Grundkenntnisse in der ABAP-Programmierung vonnöten.

Textablage

Im SAP-Standard ist für die Ablage der Kontierungsinformationen zu einem Konto, die Text-ID 0001 (Kontierungsinfo) des Textobjektes SKB1 (Sachkontentexte im Buchungskr.) vorgesehen. Der technische Name des jeweiligen Textbausteins setzt sich aus der 10-stelligen Kontonummer (ggf. mit führenden Nullen) und dem Schlüssel des Buchungskreises (4-stellig) zusammen (Beispiel: Konto 4711, Buchungskreis 0001: 00000047110001). Diese Texte können in der Buchungskreissicht des Sachkontos mithilfe der Sachkontenpflege FS00 hinterlegt werden.

Um sich die so gepflegten Kontierungsinformationen anzeigen zu lassen, kann der Standardreport "Kontierungshandbuch" ausgeführt werden. Der Bericht ist im Infosystem des Hauptbuchs, Bereich "Stammdaten" zu finden (Transaktion S_ALR_87012330 - Kontierungshandbuch).

Unter S/4 wurde diese Transaktion als obsolet gekennzeichnet und ist nicht mehr aufrufbar. Um dies bei Bedarf dennoch zu ermöglichen, bitte gemäß Hinweis 2393666 vorgehen.

Um die Pflege der Kontierungsinformationen zu vereinfachen, habe ich mal in einem Kundenprojekt ein kleines Uploadprogramm geschrieben, welches eine entsprechend aufbereitete Excel-Vorlage hochladen kann.

Excel-Vorlage:

Wenn in der Vorlage buchungskreisspezifische Texte hinterlegt werden sollen, ist der Buchungskreis in der entsprechenden Spalte anzugeben. Ist der Wert in der Spalte "Buchungskreis" leer, wird der Text in allen Buchungskreisen, in denen das Konto vorhanden ist und die den angegebenen Kontenplan verwenden, aktualisiert.

Die Felder Kontenplan, Konto, Sprache und Text sind obligatorisch. Führende Nullen bei der Angabe des Kontos können weggelassen werden. Das Programm füllt dies automatisch auf. Der Buchungskreis ist ggf. mit führenden Nullen einzugeben.

Bei der Ausführung des Upload-Programms ist lediglich die Excel-Datei auszuwählen (sie kann ohne vorherige Umformatierung direkt im XLSX-Format verwendet werden) und ggf. anzukreuzen, ob bereits manuell gepflegte Texte bei diesem Lauf überschrieben werden sollen. 

Coding:

REPORT ystxupl1.
*&---------------------------------------------------------------------*
*& Report YSTXUPL1
*&---------------------------------------------------------------------*
*& Upload SAPScript-Texts for accounting manual from Excel
*&---------------------------------------------------------------------*

DATA: data_tab TYPE TABLE OF string.

TYPES: BEGIN OF ty_txt,
         ktopl    TYPE t001-ktopl,
         bukrs    TYPE t001-bukrs,
         spras(2) TYPE c,
         saknr    TYPE skb1-saknr,
         txt      TYPE string,
       END OF ty_txt.

TYPES: tty_bukrs TYPE TABLE OF bukrs,
       tty_t001  TYPE TABLE OF t001.

DATA:  wa_txt TYPE ty_txt.
DATA:  it_txt TYPE TABLE OF ty_txt.

*&---------------------------------------------------------------------*
*& SELECTION-SCREEN
*&---------------------------------------------------------------------*
PARAMETERS: pa_fnam LIKE rlgrap-filename OBLIGATORY. "Excelfilename
PARAMETERS: pa_xovr AS CHECKBOX DEFAULT space.       "Overwrite y/n

*&---------------------------------------------------------------------*
AT SELECTION-SCREEN ON VALUE-REQUEST FOR pa_fnam.
*&---------------------------------------------------------------------*
  PERFORM f4_filename.

START-OF-SELECTION.
  PERFORM upload_data.
  PERFORM save_texts.

*&---------------------------------------------------------------------*
*& Form UPLOAD_DATA
*&---------------------------------------------------------------------*
*& upload accounting manual template (Excel)
*&---------------------------------------------------------------------*
FORM upload_data .

  DATA: l_buf   TYPE string,
        l_tabix TYPE sy-tabix.

  CLEAR data_tab[].

  CALL FUNCTION 'FAA_FILE_UPLOAD_EXCEL'
    EXPORTING
      i_filename           = pa_fnam
      i_delimiter          = '~'
    TABLES
      et_filecontent       = data_tab
    EXCEPTIONS
      error_accessing_file = 1
      OTHERS               = 2.

  IF sy-subrc <> 0.
    WRITE: / 'Fehler', sy-subrc, 'beim Upload der Datei', pa_fnam.
  ENDIF.

  LOOP AT data_tab INTO l_buf.
    CHECK sy-tabix > 1.  "Skip Header
    SPLIT l_buf AT '~' INTO
         wa_txt-ktopl
         wa_txt-bukrs
         wa_txt-spras
         wa_txt-saknr
         wa_txt-txt.

*   clean up multiple text lines.
    IF wa_txt-txt(1) = '"'.
      SHIFT wa_txt-txt BY 1 PLACES LEFT.
    ENDIF.
    DATA(l_lastchar) = strlen( wa_txt-txt ) - 1.
    IF wa_txt-txt+l_lastchar(1) = '"'.
      wa_txt-txt = wa_txt-txt(l_lastchar).
    ENDIF.

    APPEND wa_txt TO it_txt.
  ENDLOOP.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form F4_FILENAME
*&---------------------------------------------------------------------*
*& F4 help Excel-file
*&---------------------------------------------------------------------*
FORM f4_filename .

  CALL FUNCTION 'FAA_FILE_F4'
    EXPORTING
      i_default_extension = 'XLS'
    IMPORTING
      e_filename          = pa_fnam
    EXCEPTIONS
      interface_error     = 1
      OTHERS              = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form save_texts
*&---------------------------------------------------------------------*
*& Process accounting manual texts and save them
*&---------------------------------------------------------------------*
FORM save_texts .

  DATA: lt_lines TYPE TABLE OF tline,
        l_name   TYPE thead-tdname,
        l_saknr  TYPE skb1-saknr,
        lt_t001  TYPE tty_t001,
        l_spras  TYPE t001-spras,
        lt_bukrs TYPE tty_bukrs.

  LOOP AT it_txt INTO wa_txt.

*   convert external data into SAP format, if necessary
    CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
      EXPORTING
        input  = wa_txt-saknr
      IMPORTING
        output = wa_txt-saknr.
    CALL FUNCTION 'CONVERSION_EXIT_ALPHA_OUTPUT'
      EXPORTING
        input  = wa_txt-spras
      IMPORTING
        output = l_spras.

*   select company codes assigned to chart of acc.
*   in case company code isn't specified in excel template
    IF lt_t001[] IS INITIAL.
      SELECT * FROM t001 INTO TABLE lt_t001 WHERE ktopl = wa_txt-ktopl.
    ENDIF.

    IF wa_txt-bukrs IS INITIAL.
      PERFORM find_company_codes USING    wa_txt-ktopl
                                          wa_txt-saknr
                                          lt_t001
                                 CHANGING lt_bukrs.
    ELSE.
      CLEAR lt_bukrs[].
      APPEND wa_txt-bukrs TO lt_bukrs.
    ENDIF.

    LOOP AT lt_bukrs INTO wa_txt-bukrs.

      CONCATENATE wa_txt-saknr wa_txt-bukrs INTO l_name.

      IF pa_xovr IS INITIAL.
        CALL FUNCTION 'READ_TEXT'
          EXPORTING
            id                      = '0001'
            language                = l_spras
            name                    = l_name
            object                  = 'SKB1'
          TABLES
            lines                   = lt_lines
          EXCEPTIONS
            id                      = 1
            language                = 2
            name                    = 3
            not_found               = 4
            object                  = 5
            reference_check         = 6
            wrong_access_to_archive = 7
            OTHERS                  = 8.
        IF sy-subrc <> 0.
          PERFORM store_text USING l_spras l_name wa_txt.
        ENDIF.
      ELSE.
        PERFORM store_text USING l_spras l_name wa_txt.
      ENDIF.

    ENDLOOP.

  ENDLOOP.

ENDFORM.

*&---------------------------------------------------------------------*
*& Form find_company_codes
*&---------------------------------------------------------------------*
*& Select all company codes with given chart of accounts
*&---------------------------------------------------------------------*
*&      --> pi_KTOPL
*&      --> pi_SAKNR
*&      --> pt_t001
*&      <-- pt_BUKRS
*&---------------------------------------------------------------------*
FORM find_company_codes  USING    pi_ktopl TYPE t001-ktopl
                                  pi_saknr TYPE skb1-saknr
                                  pt_t001  TYPE tty_t001
                         CHANGING pt_bukrs TYPE tty_bukrs.

  CLEAR pt_bukrs[].
  LOOP AT pt_t001 ASSIGNING FIELD-SYMBOL(<lfs_t001>).
    SELECT SINGLE COUNT(*) FROM skb1
           WHERE saknr = pi_saknr
             AND bukrs = <lfs_t001>-bukrs.
    IF sy-subrc = 0.
      APPEND <lfs_t001>-bukrs TO pt_bukrs.
    ENDIF.
  ENDLOOP.

ENDFORM.
*&---------------------------------------------------------------------*
*& Form store_text
*&---------------------------------------------------------------------*
*& Put SAPScript-Tests for accouting mmanual in DB
*&---------------------------------------------------------------------*
*&      --> pi_SPRAS  Language
*&      --> pi_NAME   Textname
*&      --> pi_TXT    Text
*&---------------------------------------------------------------------*
FORM store_text  USING    pi_spras TYPE t001-spras
                          pi_name  TYPE thead-tdname
                          pi_txt   LIKE wa_txt.

  DATA: lt_tline TYPE tline_t.
  DATA: ls_header TYPE thead.

  DATA(lt_strings) = VALUE string_table( ( pi_txt-txt ) ).

* Stringtabelle -> TLINE-Tabelle
* SAPscript: Konvertieung Textstream nach ITF f¸r TextEditControl
  CALL FUNCTION 'CONVERT_STREAM_TO_ITF_TEXT'
    EXPORTING
      stream_lines = lt_strings
      lf           = abap_true
    TABLES
      itf_text     = lt_tline.

  ls_header-tdobject = 'SKB1'.
  ls_header-tdname   = pi_name.
  ls_header-tdspras  = pi_spras.
  ls_header-tdid     = '0001'.
  CALL FUNCTION 'SAVE_TEXT'
    EXPORTING
      header          = ls_header
      savemode_direct = 'X'
    TABLES
      lines           = lt_tline.

ENDFORM.

Interaktive Anzeige der Kontierungsinformationen

Um nun die so gepflegten Texte während des Buchens zur Anzeige zu bringen, implementieren wir die Business Transaction Events (BTE) 00001070 bzw. 00001080 (P/S-Schnittstelle). Details zur Implementierung von BTEs finden sich u.a. hier.

Mustercoding zur Implementierung der BTE-Bausteine:

BTE 00001070

FUNCTION y_interface_00001070.
*"--------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     REFERENCE(I_BKPF) TYPE  BKPF
*"     REFERENCE(I_BSEG) TYPE  BSEG
*"     REFERENCE(I_AKTYP) TYPE  AKTYP
*"     REFERENCE(I_DYNCL) TYPE  DYNCL
*"  EXPORTING
*"     REFERENCE(E_XCHNG) LIKE  OFIWA-XCHNG
*"--------------------------------------------------------------------
  DATA: lv_tdname   TYPE stxh-tdname,
       lv_tdobject TYPE stxh-tdobject VALUE 'SKB1',
       lv_tdid     TYPE stxh-tdid VALUE '0001'.

  CONCATENATE i_bseg-hkont i_bkpf-bukrs INTO lv_tdname.

  CALL FUNCTION 'RECA_GUI_TEXTEDIT_POPUP'
    EXPORTING
      id_tdobject = lv_tdobject
      id_tdname   = lv_tdname
      id_tdid     = lv_tdid
      id_activity = '03'
      id_title    = TEXT-002.

ENDFUNCTION.

TEXT-002 enthält dabei die Überschrift der Dialogbox, in der die Kontierungsinformation angezeigt wird.

BTE 00001080

FUNCTION y_interface_00001080.
*"--------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     REFERENCE(I_SPRAS) LIKE  SY-LANGU
*"     REFERENCE(I_AKTYP) TYPE  AKTYP
*"     REFERENCE(I_DYNCL) TYPE  DYNCL
*"  EXPORTING
*"     VALUE(E_FTEXT) LIKE  FTEXTS-FTEXT
*"--------------------------------------------------------------------

  e_ftext = TEXT-001.

ENDFUNCTION.

TEXT-001 enthält dabei die Aufschrift der Drucktaste, die in den Buchungstransaktionen zusätzlich eingeblendet wird, also z.B. "Kontierungshandbuch".

Im Ergebnis erscheint im Detailbild der Belegerfassung (z.B.in der FB01 oder bei der FB60, wenn ein Doppelklick auf die zu erfassende Belegzeile erfolgt) eine neue Drucktaste. Beim Betätigen der Drucktaste wird die zum aktuellen Konto/Buchungskreis hinterlegte Kontierungsinformation in einer Dialogbox angezeigt.

Der Pivot-Browser (PIVB) ist ein neues Ausgabe-Framework der SAP, welches die Anzeige beliebiger (strukturierter) Dateninhalte in Tabellenform ermöglicht. Die Art der Darstellung der Daten ist dabei an das bekannte ALV-Grid angelehnt. Im Unterschied zum ALV geht der Funktionsumfang des Pivot-Browsers jedoch über die reine Aufbereitung und Anzeige der Daten hinaus. Auch die Datenbeschaffung (HANA-optimiert) sowie die Behandlung von Benutzerinteraktionen ist in das Framework integriert. 

Details hierzu finden sich in den PDF-Anhängen zum Hinweis 2100879 - Pivot Browser: Dokumentation

Einige der im Standard ausgelieferten Funktionalitäten, die auf dem Pivot-Browser basieren, sind die Einzelpostenbrowser in der S/4 Finanzbuchhaltung:

Während der Anzeige-Bereich (links) weitestgehend identisch zum bekannten ALV funktioniert, ist der Interaktionsbereich (rechts) ein neu gestaltetes Element im Pivot-Browser. 

Im Bereich Spalten können die anzuzeigenden Felder ausgewählt werden. Bei den o.g. FI-Einzelpostenbrowsern stehen gegen Ende der Liste auch Stammdatenfelder und Bezeichnungen zur Verfügung. So kann bspw. zur Kostenstelle die entsprechende Kostenstellenbezeichnung in die Anzeige geholt werden, ohne wie bei den klassischen Einzelpostenlisten (FBLxN) den Feldvorrat erweitern und die Inhalte per BTE/BADI nachlesen zu müssen.

Der Bereich Layouts enthält alle verfügbaren Anzeigelayouts und ermöglicht deren Verwaltung wie unter ALV bekannt (entsprechende Berechtigung vorausgesetzt).

Interessant ist der Bereich Aktionen, in dem für den aktuellen Anzeigevorrat verfügbare Benutzeraktionen dargestellt sind. Diese können in einer (max. zweistufigen) Baumstruktur angeordnet werden, um so gewisse Interaktionen zu gruppieren. 

Sie ahnen es wahrscheinlich schon, dieser Bereich lässt sich modifikationsfrei beliebig erweitern und mit kundenspezifischen Aktionen spicken...

Weiter unten möchte ich ein Beispiel für eine solche kundeneigene Aktion zeigen, das die Erzeugung von Abgrenzungsobjekten der Accrual Engine bzw. des Accruals Management (ab S/4 1809) direkt aus den Einzelpostenbrowsern der Finanzbuchhaltung ermöglicht.

Die einzelnen Anwendungen des Pivot-Browsers werden als Erweiterungsimplementierung des Erweiterungsspots PIVB registriert. Für die EP-Browser im FI (s.o.) ist dies die Implementierung FAGL_LIB_PIVB. In ihr wiederum werden die Implementierungen zur BadI-Definition FAGL_LIB gerufen, zu der auch kundeneigene Implementierungen angelegt werden können.

Für die Aktionen sind die beiden Interface-Methoden SIDEBAR_ACTIONS_SET und SIDEBAR_ACTIONS_HANDLE relevant. In ersterer kann der "Aktionsbaum" um kundeneigene Aktionen erweitert werden, in der zweitgenannten Methode wird dann die eigentliche Aktion ausgestaltet.

Fügen wir also zunächst eine Aktion in einem kundeneigenen Ordner hinzu:

METHOD if_fagl_lib~sidebar_actions_set.

*   Kundeneigene Aktionen im Einzelpostenbrowser 

    TYPE-POOLS: icon.

*   Neuer Ordner am Ende anfügen
    APPEND INITIAL LINE TO c_menu-t_folder_level1 ASSIGNING FIELD-SYMBOL(<lf_folder>).
    <lf_folder>-folder_key = 'ZZACE'.
    <lf_folder>-folder_text = 'Abgrenzungsobjekt'.

*   Aktion in den neuen Ordner einfügen
    APPEND INITIAL LINE TO <lf_folder>-t_item_level2 ASSIGNING FIELD-SYMBOL(<lf_menuitem>).
    <lf_menuitem>-item_key = 'ZZACE_CREATE'.
    <lf_menuitem>-text = 'Abgrenzungsobjekt anlegen'.
    <lf_menuitem>-icon = icon_fencing.

  ENDMETHOD.

...und nun kann die Aktion, die mit der ID ZZACE_CREATE angelegt wurde, ausgestaltet werden.

  METHOD if_fagl_lib~sidebar_actions_handle.

*   Kundeneigene Aktionen im Einzelpostenbrowser 

    DATA: l_checker TYPE i.
    DATA: ls_bseg TYPE bseg.
    DATA: ls_bkpf TYPE bkpf.

    l_checker = 0.

    CASE i_navigate_item_key.
      WHEN 'ZZACE_CREATE'.   "Abgrenzungsobjekt anlegen
        IF it_outtab_selected_rows[] IS NOT INITIAL.                                            "Mind. eine Zeile selektiert?
          LOOP AT it_column ASSIGNING FIELD-SYMBOL(<lf_col>) WHERE fieldname = 'BUKRS' OR       "Felder Bukrs, Belnr, Gjahr und Buzei in Liste?
                                                                   fieldname = 'BELNR' OR
                                                                   fieldname = 'GJAHR' OR
                                                                   fieldname = 'BUZEI'.
            IF <lf_col>-is_invisible = abap_false.
              ADD 1 TO l_checker.
            ENDIF.
          ENDLOOP.
          IF l_checker < 4.
            MESSAGE 'Bitte mind. BUKRS BELNR GJAHR BUZEI in Anzeige holen' TYPE 'I'.
            EXIT.
          ELSE.
            "Belegdaten nachlesen
            READ TABLE it_outtab INDEX it_outtab_selected_rows[ 1 ]-row_id ASSIGNING FIELD-SYMBOL(<lf_row>).
            MOVE-CORRESPONDING <lf_row> TO ls_bseg.
            SELECT SINGLE * FROM bkpf INTO ls_bkpf
                    WHERE bukrs = ls_bseg-bukrs
                      AND belnr = ls_bseg-belnr
                      AND gjahr = ls_bseg-gjahr.
            SELECT SINGLE * FROM bseg INTO ls_bseg
                    WHERE bukrs = ls_bkpf-bukrs
                      AND belnr = ls_bkpf-belnr
                      AND gjahr = ls_bkpf-gjahr
                      AND buzei = ls_bseg-buzei.
            IF sy-subrc = 0.
              "Aufruf Generierungsprogramm f. Abgrenzungsobjekte
              ls_bseg-dmbtr = abs( ls_bseg-dmbtr ).         "Abgrenzungsbetrag muss positiv sein
              IF ls_bseg-koart NE 'S'.                      "Kontokorrente (FBL1H)
                SUBMIT zacac_d_trans_s4 AND RETURN VIA SELECTION-SCREEN
                       WITH p_check  = 'X'
                       WITH p_efdate = sy-datum
                       WITH p_powip = 'X'
                       WITH so_acmth = 'LINEAR'
                       WITH so_acpst = ls_bkpf-budat
                       WITH so_belnr = ls_bkpf-belnr
                       WITH so_bukrs = ls_bkpf-bukrs
                       WITH so_gjahr = ls_bkpf-gjahr
                       WITH p_amnt   = ls_bseg-dmbtr
                       WITH p_text   = ls_bseg-sgtxt.
              ELSE.                                          "FAGLL03H, FBL3H
                SUBMIT zacac_d_trans_s4 AND RETURN VIA SELECTION-SCREEN
                        WITH p_check  = 'X'
                        WITH p_efdate = sy-datum
                        WITH p_powoip = 'X'                  "Bei Sachkontenposten - OHNE Eröffnungbuchung als Default
                        WITH p_powip  = space
                        WITH so_acmth = 'LINEAR'
                        WITH so_acpst = ls_bkpf-budat
                        WITH so_belnr = ls_bkpf-belnr
                        WITH so_bukrs = ls_bkpf-bukrs
                        WITH so_buzei = ls_bseg-buzei
                        WITH so_gjahr = ls_bkpf-gjahr
                        WITH p_amnt   = ls_bseg-dmbtr
                        WITH p_text   = ls_bseg-sgtxt.
              ENDIF.
            ENDIF.
          ENDIF.
        ENDIF.
    ENDCASE.
  ENDMETHOD.

Da der Pivot-Browser HANA optimiert ist, werden nur die Spalten gelesen, die auch im aktuellen Layout benötigt werden. Dies ist ein wesentlicher Unterschied zu den klassischen EP-Listen, die immer alle Spalten eines Postens lesen, unabhängig von deren Verwendung in der Anzeige.

D.h., es muss zunächst geprüft werden, ob die für die weitere Verarbeitung benötigten Felder auch zur Verfügung stehen!

Im weiteren Verlauf dieses Beispiels wird eine angepasste Z-Kopie des Demo-Reports ACAC_D_TRANS_EXAMPLE_S4 gerufen, der aus einem vorgegebenen Belegvorrat Abgrenzungsobjekte im Accruals Management generiert. Für die "alte" Accrual Engine (vor S/4 1809) wäre dies der Report ACAC_DATA_TRANSFER_EXAMPLE.

Sind die Anforderungen an die WE/RE-Kontenfindung durch das Standardcustomizing (Vorgang ‚WRX’) nicht zu bedienen, kann eine sog. Kontomodifikation verwendet werden, die über die SAP-Erweiterung LMR1M002 (User Exit) bestelldatenabhängig gesetzt werden kann. Im Customizing werden dann die WE/RE-Konten in Abhängigkeit von der im Userexit versorgten Kontomodifikation in folgender Form gesetzt:

Kontomodifikation - WE/RE-Konto

IMG: Finanzwesen > Hauptbuch > Geschäftsvorfälle > Integration > Materialwirtschaft > Konten für Materialwirtschaft hinterlegen (Vorgang WRX)

Ein konkreter Anwendungsfall könnte z.B. sein, dass im Rahmen der buchungskreisübergreifenden Umlagerung (Szenario ‚Cross Company Nachschub') für die internen Wareneingänge und Rechnungen ein separates WE/RE-Konto gefunden werden soll:

Beispielcoding:

Funktionsbaustein EXIT_SAPLKONT_011, Include ZXM08U18

Zwei, drei mal wurde in den letzen Jahren in den einschlägigen deutschsprachigen FICO-Foren nach einer Auswertung von Nettoumsätzen von Debitoren bzw. Kreditoren gefragt. Da der SAP Standard sich hierbei eher bedeckt hält, lief es meist auf einen Z-Report hinaus. 

Eine Lösung, die in die einschlägigen EP-Listen (FBLxN) integriert ist, hat FICO-Forum User Frank Thielemann freundlicherweise zur Verfügung gestellt:

Link

Es handelt sich um einen Ansatz, der die Erweiterungsmöglichkeiten der EP-Listen via Business Transaction Event (BTE) nutzt. Alternativ kann auch das BadI FAGL_ITEMS_CH_DATA herhalten. Details hierzu siehe hier, Abschnitt "Hinzufügen eigener Felder".